[Excel VBA]将一个工作表，以某列为依据拆分成多个工作表

熊阿初 • 2022年11月9日下午4:42 • 代码及教程 • 阅读 453

将一个工作表，拆分成多个工作表。
拆分依据为指定列，指定列相同的拆分至同一个工作表。
可以定义拆分后的工作表保留的原表标题行数。
比如将下表

以姓名为指定列拆分成多个sheet，保留行数为3


Private Sub CommandButton1_Click()

    Dim d As Object, sht As Worksheet, arr, brr, r, kr, i&, j&, k&, x&
    Dim Rng As Range, Rg As Range, tRow&, tCol&, aCol&, pd&
    Application.ScreenUpdating = False '关闭屏幕更新
    Application.DisplayAlerts = False '关闭警告信息提示
    Set d = CreateObject("scripting.dictionary") 'set字典
    Dim tip
    tip = MsgBox("将会把本页的表格拆为多个工作表，为保证分拆后的表格版式，请仅保留标题行与正式数据的第一行的边框，弹出的输入框，未填写内容时可能会报错，同名老师请先在姓名中区别清楚", vbOKCancel)
    If tip <> 1 Then
    Exit Sub
    End If
    Set Rg = Application.InputBox("请选择姓名列！选择姓名列的一个单元格即可！", Title:="提示", Type:=8)
    '用户选择的拆分依据列
    tCol = Rg.Column '取拆分依据列列标
    tRow = Val(Application.InputBox("请输入总表标题行的行数？"))
    '用户设置总表的标题行数
    If tRow = 0 Then
    MsgBox "你未输入标题行行数，程序退出。": Exit Sub
    End If
    Set Rng = ActiveSheet.UsedRange '总表的数据区域
    arr = Rng '数据范围装入数组arr
    tCol = tCol - Rng.Column + 1 '计算依据列在数组中的位置
    aCol = UBound(arr, 2) '数据源的列数
    For i = tRow + 1 To UBound(arr) '遍历数组arr
        If Not d.exists(arr(i, tCol)) Then
            d(arr(i, tCol)) = i '字典中不存在关键词则将行号装入字典
        Else
            d(arr(i, tCol)) = d(arr(i, tCol)) & "," & i '如果存在则合并行号，以逗号间隔
        End If
    Next
    For Each sht In Worksheets '遍历一遍工作表，如果字典中存在则删除
        If d.exists(sht.Name) Then sht.Delete
    Next
    kr = d.keys '字典的key集
    For i = 0 To UBound(kr) '遍历字典key值
        If kr(i) <> "" Then '如果key不为空
            r = Split(d(kr(i)), ",") '取出item里储存的行号
            ReDim brr(1 To UBound(r) + 1, 1 To aCol) '声明放置结果的数组brr
            k = 0
            For x = 0 To UBound(r)
                k = k + 1 '累加记录行数
                For j = 1 To aCol '循环读取列
                    brr(k, j) = arr(r(x), j)
                Next
            Next
            With Worksheets.Add(, Sheets(Sheets.Count))
            '新建一个工作表，位置在所有已存在sheet的后面
                .Name = kr(i) '表格命名
                .[A1].Resize(tRow, aCol) = arr '放标题行
                .[A1].Offset(tRow, 0).Resize(k, aCol) = brr '放置数据区域
                Rng.Copy '复制粘贴总表的格式
                .[A1].PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
                .[A1].Select
            End With
        End If
    Next
    Sheets(1).Activate '激活第一个表格
    Set d = Nothing '释放字典
    Erase arr: Erase brr '释放数组
    MsgBox "数据拆分完成！"
    Application.ScreenUpdating = True '恢复屏幕更新
    Application.DisplayAlerts = True '恢复警示
End Sub

原创文章，作者：熊阿初，如若转载，请注明出处：https://www.guofc.com/344.html

[Excel VBA]将一个工作表，以某列为依据拆分成多个工作表

相关推荐

发表回复